「電子書籍のサービス終了に備える」（第4回）楽天Kobo (1)キャプチャ編

WID = GETID("楽天Koboデスクトップ")
IF WID < 0 then
    MSGBOX("楽天Koboデスクトップ が起動していません")
    EXIT
ENDIF

book_type = SLCTBOX(SLCT_RDO, 0, "画面サイズ変更のため本の種類を選択してください", "コミック", "文庫", "画面サイズ変更なし")
SELECT book_type
    CASE SLCT_1
        // コミック：画面位置サイズ（★ 変更要）
        pos_x = 1
        pos_y = 1
        width = 1576
        height = 1199
    CASE SLCT_2
        // 文庫：画面位置サイズ（★ 変更要）
        pos_x = 1
        pos_y = 1
        width = 942
        height = 1199
    CASE SLCT_3
        // 画面サイズの変更を行わない
        pos_x = 1
        pos_y = 1
        width = 0
        height = 0
SELEND

// の画面サイズと位置を変更して、タイトルバーをクリック（アクティブにする）
IF width <> 0 THEN ACW(WID, pos_x, pos_y, width, height, 0) ELSE ACW(WID, pos_x, pos_y)
BTN(LEFT, CLICK, 50, 10, 40)
SLEEP(0.5)

next_page_key_select = SLCTBOX(SLCT_RDO, 0, "ページ切り替えのキーを選択してください", "←:左矢印", "→:右矢印")
SELECT next_page_key_select
    CASE SLCT_1
        next_key = VK_LEFT
    CASE SLCT_2
        next_key = VK_RIGHT
SELEND

// ページ切り替え間隔を入力
sleep_sec = 0
WHILE TRUE
    sleep_sec_str = INPUT("ページ切り替え間隔（秒）を入力してください")
    IFB VARTYPE(sleep_sec_str) = VAR_EMPTY
        EXIT    // [キャンセル]
    ELSE
        sleep_sec = VAL(sleep_sec_str)
        IFB sleep_sec = ERR_VALUE 
            CONTINUE    // 入力エラー(数字以外)
        ENDIF
        BREAK
    ENDIF
WEND

MSGBOX("キャプチャの準備（[矩形範囲設定]まで）を実施後 OKを押下してください。")

ACW(WID,1,1)
BALLOON("キャプチャを開始してください。10秒後にページ切り替えを開始します。")
SLEEP(10)
BALLOON()

WHILE TRUE
    GETTIME()
    n = G_TIME_SS MOD sleep_sec
    IFB n = 0 THEN
        // 時刻（秒）を間隔（秒）で割った余りが 0 のときページ切り替え
        //   3秒間隔 = 0,3,6,・・・・,57
        //   4秒間隔 = 0,4,8,・・・・,56
        IF width <> 0 THEN ACW(WID, pos_x, pos_y, width, height, 0) ELSE ACW(WID, pos_x, pos_y)
        BTN(LEFT, CLICK, 50, 10, 40)
        SLEEP(0.1)

        KBD(next_key, CLICK, 10)

        // 時刻（秒）が変わるのを待つ
        SLEEP(1.2)
    ELSE
        SLEEP(0.1)
    ENDIF
WEND

// VMware の WindowID を取得
WID = GETID("Win10 - VMware Workstation") // ウィンドウタイトル（★変更要）
IF WID < 0 then
    MSGBOX("VMware が起動していません")
    EXIT
ENDIF
ACW(WID, 1, 1, 1922, 1257, 0)  // VMwareの画面位置サイズ（★ 変更要）

// メモ帳起動について
//   VMwareがアクティブの時に、(CTRL + ALT + F7)でキャプチャしようとしてもキャプチャできない。
//   おそらくキー入力が VMware側のOSに取られてしまうのではないかと思われる。
//   キャプチャ前にメモ帳をアクティブ（VMwareを非アクティブ）にすることで対応。
//  （★メモ帳以外のアプリに変更してもOKです。普段使用しないものがいいかも)
SLEEP(0.2)
NOTEPAD_WID = GETID("メモ帳")
IFB NOTEPAD_WID < 0 THEN
    EXEC("notepad.exe")
    NOTEPAD_WID = GETID("メモ帳")
    IFB NOTEPAD_WID < 0 THEN
        MSGBOX("メモ帳を起動できません")
        EXIT
    ENDIF
ENDIF
ACW(NOTEPAD_WID, 1995, 70, 300, 225, 0) // ★変更要：メモ帳の位置サイズ

book_type = SLCTBOX(SLCT_RDO, 0, "キャプチャする本の種類を選択してください", "コミック", "文庫")
SELECT book_type
    CASE SLCT_1
        // コミック：画面位置（左上、右下）（★ 変更要）
        pos_x1 = 4
        pos_y1 = 173
        pos_x2 = 1578
        pos_y2 = 1255
    CASE SLCT_2
        // 文庫：画面位置（左上、右下）（★ 変更要）
        pos_x1 = 100
        pos_y1 = 181
        pos_x2 = 848
        pos_y2 = 1219
SELEND

// キャプチャ間隔を入力
sleep_sec = 0
WHILE TRUE
    sleep_sec_str = INPUT("キャプチャ間隔（秒）を入力してください")
    IFB VARTYPE(sleep_sec_str) = VAR_EMPTY THEN
        EXIT    // [キャンセル]
    ELSE
        sleep_sec = VAL(sleep_sec_str)
        IFB sleep_sec = ERR_VALUE THEN
            CONTINUE    // 入力エラー(数字以外)
        ENDIF
        BREAK
    ENDIF
WEND

MSGBOX("WinShotの [矩形範囲設定] - [前回の矩形範囲修正] で (" + pos_x1 + "," + pos_y1 + ") (" + pos_x2 + "," + pos_y2 + ")を設定後、OKを押下してください")
MSGBOX("キャプチャを開始します。ページ切り替え開始後、OKを押下してください")

BALLOON(sleep_sec + "秒間隔でキャプチャしています。ESC押下で終了できます")
SLEEP(1)

WHILE TRUE
    GETTIME()
    n = G_TIME_SS MOD sleep_sec
    IFB n = 2 THEN
        // 現在時刻（秒）を間隔（秒）で割った余りが 2 のときキャプチャ
        //   3秒間隔 = 2,5,8,・・・・,59
        //   4秒間隔 = 2,6,10,・・・・,58

        // VMwareを非アクティブ化 (VMware がアクティブだとキャプチャできない)
        ACW(NOTEPAD_WID, 1995, 70, 300, 225, 0)
        SLEEP(0.1)

        // キャプチャ（CTRL + ALT + F7）
        KBD(VK_CTRL,DOWN,40)
        KBD(VK_ALT,DOWN,0)
        KBD(VK_F7,CLICK,40)
        KBD(VK_ALT,UP,40)
        KBD(VK_CTRL,UP,0)

        IF GETKEYSTATE(VK_ESC) THEN BREAK

        // 現在時刻（秒）が変わるのを待つ
        SLEEP(1.2)
    ENDIF

    // 「楽天Koboデスクトップ」の「ライブラリ」の下のバーの色で終了するかどうか判断する
    red_color = PEEKCOLOR(160, 137, COL_R)   // バーの位置（★ 変更要）
    IFB red_color < 200 THEN
        // 楽天Kobo のメニュー部「ライブラリ」の下が朱色になったら終了
        // RGB の R で判断
        //    ページ切り替え中 = 灰色 245
        //    ページ切り替え終了 = 朱色 191
        BREAK
    ENDIF

    SLEEP(0.1)
WEND

// メモ帳を終了
CTRLWIN(NOTEPAD_WID, CLOSE)