「電子書籍のサービス終了に備える」（第2回）Kindle (1)キャプチャ編

// Kindle for PC の WindowID を取得
WID = GETID("Kindle for PC")
IF WID < 0 then
    MSGBOX("Kindle for PC が起動していません")
    EXIT
ENDIF

book_type = SLCTBOX(SLCT_RDO, 0, "画面サイズ変更のため本の種類を選択してください", "コミック", "文庫", "画面サイズ変更なし")
SELECT book_type
    CASE SLCT_1
        // コミック：画面位置サイズ（★ 変更要）
        pos_x = 1
        pos_y = 1
        width = 1693
        height = 1193
    CASE SLCT_2
        // 文庫：画面位置サイズ（★ 変更要）
        pos_x = 1
        pos_y = 1
        width = 806
        height = 1060
    CASE SLCT_3
        // 画面サイズの変更を行わない
        pos_x = 1
        pos_y = 1
        width = 0
        height = 0
SELEND

// Kindle for PC の画面サイズと位置を変更して、タイトルバーをクリック（アクティブにする）
MOUSEORG(0)
IF width <> 0 THEN ACW(WID, pos_x, pos_y, width, height, 0) ELSE ACW(WID, pos_x, pos_y)
MOUSEORG(WID)
BTN(LEFT, CLICK, 50, 10, 40)
SLEEP(0.5)

// キャプチャする回数を入力
capture_count = 0
WHILE TRUE
    capture_count_str = INPUT("キャプチャする回数を入力してください")
    IFB VARTYPE(capture_count_str) = VAR_EMPTY
        EXIT    // [キャンセル]
    ELSE
        capture_count = VAL(capture_count_str)
        IFB capture_count = ERR_VALUE 
            CONTINUE    // 入力エラー(数字以外)
        ENDIF
        BREAK
    ENDIF
WEND

// タイトルバーの色
title_color = PEEKCOLOR(5, 15)

FOR cnt = 1 TO capture_count
    // Kindle for PC の画面サイズと位置を変更して、タイトルバーをクリック（アクティブにする）
    // （処理中にマウスクリック等されてもできるだけ動作するようにループ内で毎回実施）
    MOUSEORG(0)
    IF width <> 0 THEN ACW(WID, pos_x, pos_y, width, height, 0) ELSE ACW(WID, pos_x, pos_y)
    MOUSEORG(WID)
    BTN(LEFT, CLICK, 50, 10, 40)
    SLEEP(0.5)  // ★修正要：タイミング調整

    // キャプチャ（ALT + ScreenShot）
    KBD(VK_ALT, DOWN, 40)
    KBD(VK_SNAPSHOT, CLICK, 40)
    KBD(VK_ALT, UP, 40)

    SLEEP(0.5)   // ★修正要：タイミング調整

    // ALT押下状態（タイトルバーとメニューの背景色が違えば）ALTをクリックし ALT押下状態を解除
    // （これが無いと次の ↓キーで ファイルメニュー部が表示される）
    menu_color = PEEKCOLOR(5, 40)
    IF title_color <> menu_color THEN KBD(VK_ALT, CLICK, 40)

    // 次ページ（↓キー）
    SLEEP(0.1)
    BTN(LEFT, CLICK, 50, 10, 0)
    KBD(VK_DOWN, CLICK, 30)

    // ページ切り替えを待つ
    // → ★PCの性能で必要な待ち時間が変わると思われるため時間は調整してください
    //      ・短すぎたら同じページが2回キャプチャされる
    //      ・長すぎたら完了までの時間が長くなる
    SLEEP(1)

    // ESCが押下されたら中断しループを抜ける
    IF GETKEYSTATE(VK_ESC) THEN BREAK
NEXT